Initial Commit

resources/eagler/glsl/accel_font.fsh

@@ -0,0 +1,32 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN(vec2, v_texCoord2f)
+EAGLER_IN(vec4, v_color4f)
+
+EAGLER_FRAG_OUT()
+
+uniform sampler2D u_inputTexture;
+uniform vec4 u_colorBias4f;
+
+void main() {
+	EAGLER_FRAG_COLOR = EAGLER_TEXTURE_2D(u_inputTexture, v_texCoord2f) * v_color4f + u_colorBias4f;
+	if(EAGLER_FRAG_COLOR.a < 0.004) {
+		discard;
+	}
+}

resources/eagler/glsl/accel_font.vsh

@@ -0,0 +1,50 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_VSH_LAYOUT_BEGIN()
+EAGLER_IN(0, vec3, a_position3f)
+EAGLER_IN(1, vec2, c_position2i)
+EAGLER_IN(2, vec2, c_coords2i)
+EAGLER_IN(3, vec4, c_color4f)
+EAGLER_VSH_LAYOUT_END()
+
+EAGLER_OUT(vec2, v_texCoord2f)
+EAGLER_OUT(vec4, v_color4f)
+
+uniform mat4 u_matrixTransform;
+uniform vec2 u_charSize2f;
+uniform vec2 u_charCoordSize2f;
+uniform vec4 u_color4f;
+
+void main() {
+	v_color4f = c_color4f.bgra;
+	float shadowBit = a_position3f.z;
+	float boldBit = shadowBit >= 0.5 ? 1.0 : 0.0;
+	shadowBit -= boldBit * 0.5;
+	v_color4f.rgb *= (1.0 - shadowBit * 3.0);
+	v_texCoord2f = (c_coords2i + a_position3f.xy) * u_charCoordSize2f;
+	vec2 pos2d = c_position2i + vec2(shadowBit * 4.0);
+	pos2d += a_position3f.xy * u_charSize2f;
+	pos2d.x += boldBit;
+	float italicBit = v_color4f.a >= 0.5 ? 2.0 : 0.0;
+	v_color4f.a -= italicBit * 0.25;
+	pos2d.x -= (a_position3f.y - 0.5) * italicBit;
+	v_color4f.a *= 2.0;
+	v_color4f *= u_color4f;
+	EAGLER_VERT_POSITION = u_matrixTransform * vec4(pos2d, 0.0, 1.0);
+}

resources/eagler/glsl/accel_particle.fsh

@@ -0,0 +1,31 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN(vec2, v_texCoord2f)
+EAGLER_IN(vec4, v_color4f)
+
+EAGLER_FRAG_OUT()
+
+uniform sampler2D u_inputTexture;
+
+void main() {
+	EAGLER_FRAG_COLOR = EAGLER_TEXTURE_2D(u_inputTexture, v_texCoord2f) * v_color4f;
+	if(EAGLER_FRAG_COLOR.a < 0.004) {
+		discard;
+	}
+}

resources/eagler/glsl/accel_particle.vsh

@@ -0,0 +1,55 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_VSH_LAYOUT_BEGIN()
+EAGLER_IN(0, vec2, a_position2f)
+EAGLER_IN(1, vec3, p_position3f)
+EAGLER_IN(2, vec2, p_texCoords2i)
+EAGLER_IN(3, vec2, p_lightMap2f)
+EAGLER_IN(4, vec2, p_particleSize_texCoordsSize_2i)
+EAGLER_IN(5, vec4, p_color4f)
+EAGLER_VSH_LAYOUT_END()
+
+EAGLER_OUT(vec2, v_texCoord2f)
+EAGLER_OUT(vec4, v_color4f)
+
+uniform mat4 u_matrixTransform;
+uniform vec3 u_texCoordSize2f_particleSize1f;
+uniform vec3 u_transformParam_1_2_5_f;
+uniform vec2 u_transformParam_3_4_f;
+uniform vec4 u_color4f;
+
+uniform sampler2D u_lightmapTexture;
+
+void main() {
+	v_color4f = u_color4f * p_color4f.bgra * EAGLER_TEXTURE_2D(u_lightmapTexture, p_lightMap2f);
+
+	vec2 tex2f = a_position2f * 0.5 + 0.5;
+	tex2f.y = 1.0 - tex2f.y;
+	tex2f = p_texCoords2i + tex2f * p_particleSize_texCoordsSize_2i.y;
+	v_texCoord2f = tex2f * u_texCoordSize2f_particleSize1f.xy;
+
+	float particleSize = u_texCoordSize2f_particleSize1f.z * p_particleSize_texCoordsSize_2i.x;
+
+	vec3 pos3f = p_position3f;
+	vec2 spos2f = a_position2f * particleSize;
+	pos3f += u_transformParam_1_2_5_f * spos2f.xyy;
+	pos3f.zx += u_transformParam_3_4_f * spos2f;
+
+	EAGLER_VERT_POSITION = u_matrixTransform * vec4(pos3f, 1.0);
+}

resources/eagler/glsl/core.fsh

@@ -0,0 +1,199 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+#if defined(COMPILE_ENABLE_TEX_GEN) || defined(COMPILE_ENABLE_FOG)
+EAGLER_IN(vec4, v_position4f)
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+EAGLER_IN(vec2, v_texture2f)
+#endif
+
+uniform vec4 u_color4f;
+
+#ifdef COMPILE_BLEND_ADD
+uniform vec4 u_colorBlendSrc4f;
+uniform vec4 u_colorBlendAdd4f;
+#endif
+
+#ifdef COMPILE_COLOR_ATTRIB
+EAGLER_IN(vec4, v_color4f)
+#endif
+
+#ifdef COMPILE_NORMAL_ATTRIB
+EAGLER_IN(vec3, v_normal3f)
+#endif
+
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+EAGLER_IN(vec2, v_lightmap2f)
+#endif
+
+#ifdef COMPILE_ENABLE_TEXTURE2D
+uniform sampler2D u_samplerTexture;
+#if !defined(COMPILE_TEXTURE_ATTRIB) && !defined(COMPILE_ENABLE_TEX_GEN)
+uniform vec2 u_textureCoords01;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_LIGHTMAP
+uniform sampler2D u_samplerLightmap;
+#ifndef COMPILE_LIGHTMAP_ATTRIB
+uniform vec2 u_textureCoords02;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+uniform float u_alphaTestRef1f;
+#endif
+
+#ifdef COMPILE_ENABLE_MC_LIGHTING
+uniform int u_lightsEnabled1i;
+uniform vec4 u_lightsDirections4fv[4];
+uniform vec3 u_lightsAmbient3f;
+#ifndef COMPILE_NORMAL_ATTRIB
+uniform vec3 u_uniformNormal3f;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_FOG
+uniform vec4 u_fogParameters4f;
+uniform vec4 u_fogColor4f;
+#endif
+
+#ifdef COMPILE_ENABLE_TEX_GEN
+EAGLER_IN(vec3, v_objectPosition3f)
+uniform ivec4 u_texGenPlane4i;
+uniform vec4 u_texGenS4f;
+uniform vec4 u_texGenT4f;
+uniform vec4 u_texGenR4f;
+uniform vec4 u_texGenQ4f;
+uniform mat4 u_textureMat4f01;
+#endif
+
+#ifdef COMPILE_ENABLE_ANISOTROPIC_FIX
+uniform vec2 u_textureAnisotropicFix;
+#endif
+
+EAGLER_FRAG_OUT()
+
+void main() {
+
+#ifdef COMPILE_COLOR_ATTRIB
+	vec4 color = v_color4f * u_color4f;
+#else
+	vec4 color = u_color4f;
+#endif
+
+#ifdef COMPILE_ENABLE_TEX_GEN
+	vec4 tmpVec4 = vec4(v_objectPosition3f, 1.0);
+	vec4 texGenVector;
+	texGenVector.x = dot(u_texGenPlane4i.x == 1 ? v_position4f : tmpVec4, u_texGenS4f);
+	texGenVector.y = dot(u_texGenPlane4i.y == 1 ? v_position4f : tmpVec4, u_texGenT4f);
+	texGenVector.z = dot(u_texGenPlane4i.z == 1 ? v_position4f : tmpVec4, u_texGenR4f);
+	texGenVector.w = dot(u_texGenPlane4i.w == 1 ? v_position4f : tmpVec4, u_texGenQ4f);
+#ifdef EAGLER_HAS_GLES_300
+	texGenVector.xyz = mat4x3(
+		u_textureMat4f01[0].xyw,
+		u_textureMat4f01[1].xyw,
+		u_textureMat4f01[2].xyw,
+		u_textureMat4f01[3].xyw
+	) * texGenVector;
+	texGenVector.xy /= texGenVector.z;
+#else
+	texGenVector = u_textureMat4f01 * texGenVector;
+	texGenVector.xy /= texGenVector.w;
+#endif
+
+	color *= EAGLER_TEXTURE_2D(u_samplerTexture, texGenVector.xy);
+
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+	if(color.a < u_alphaTestRef1f) discard;
+#endif
+
+#else
+
+#ifdef COMPILE_ENABLE_TEXTURE2D
+#ifdef COMPILE_TEXTURE_ATTRIB
+#ifdef COMPILE_ENABLE_ANISOTROPIC_FIX
+	// d3d11 doesn't support GL_NEAREST upscaling with anisotropic
+	// filtering enabled, so it needs this stupid fix to 'work'
+	vec2 uv = floor(v_texture2f * u_textureAnisotropicFix) + 0.5;
+	color *= EAGLER_TEXTURE_2D(u_samplerTexture, uv / u_textureAnisotropicFix);
+#else
+	color *= EAGLER_TEXTURE_2D(u_samplerTexture, v_texture2f);
+#endif
+#else
+	color *= EAGLER_TEXTURE_2D(u_samplerTexture, u_textureCoords01);
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_LIGHTMAP
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+	color *= EAGLER_TEXTURE_2D(u_samplerLightmap, v_lightmap2f);
+#else
+	color *= EAGLER_TEXTURE_2D(u_samplerLightmap, u_textureCoords02);
+#endif
+#endif
+
+#ifdef COMPILE_BLEND_ADD
+	color = color * u_colorBlendSrc4f + u_colorBlendAdd4f;
+#endif
+
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+	if(color.a < u_alphaTestRef1f) discard;
+#endif
+
+#endif
+
+#ifdef COMPILE_ENABLE_MC_LIGHTING
+#ifdef COMPILE_NORMAL_ATTRIB
+	vec3 normal = normalize(v_normal3f);
+#else
+	vec3 normal = u_uniformNormal3f;
+#endif
+	float diffuse = 0.0;
+	vec4 light;
+#ifdef EAGLER_HAS_GLES_300
+	for(int i = 0; i < u_lightsEnabled1i; ++i) {
+#else
+	for(int i = 0; i < 4; ++i) {
+#endif
+		light = u_lightsDirections4fv[i];
+		diffuse += max(dot(light.xyz, normal), 0.0) * light.w;
+#ifndef EAGLER_HAS_GLES_300
+		if(i + 1 >= u_lightsEnabled1i) {
+			break;
+		}
+#endif
+	}
+	color.rgb *= min(u_lightsAmbient3f + vec3(diffuse), 1.0);
+#endif
+
+#ifdef COMPILE_ENABLE_FOG
+	vec3 fogPos = v_position4f.xyz / v_position4f.w;
+	float dist = length(fogPos);
+	float fogDensity = u_fogParameters4f.y;
+	float fogStart = u_fogParameters4f.z;
+	float fogEnd = u_fogParameters4f.w;
+	float f = u_fogParameters4f.x > 0.0 ? 1.0 - exp(-fogDensity * dist) :
+		(dist - fogStart) / (fogEnd - fogStart);
+	color.rgb = mix(color.rgb, u_fogColor4f.rgb, clamp(f, 0.0, 1.0) * u_fogColor4f.a);
+#endif
+
+	EAGLER_FRAG_COLOR = color;
+}

resources/eagler/glsl/core.vsh

@@ -0,0 +1,99 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN_AUTO(vec3, a_position3f)
+
+#if defined(COMPILE_ENABLE_TEX_GEN) || defined(COMPILE_ENABLE_FOG)
+#define _COMPILE_VARYING_POSITION
+#endif
+
+#ifdef _COMPILE_VARYING_POSITION
+EAGLER_OUT(vec4, v_position4f)
+#endif
+
+#ifdef COMPILE_ENABLE_TEX_GEN
+EAGLER_OUT(vec3, v_objectPosition3f)
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+EAGLER_IN_AUTO(vec2, a_texture2f)
+EAGLER_OUT(vec2, v_texture2f)
+uniform mat4 u_textureMat4f01;
+#endif
+
+#ifdef COMPILE_COLOR_ATTRIB
+EAGLER_IN_AUTO(vec4, a_color4f)
+EAGLER_OUT(vec4, v_color4f)
+#endif
+
+#ifdef COMPILE_NORMAL_ATTRIB
+EAGLER_IN_AUTO(vec4, a_normal4f)
+EAGLER_OUT(vec3, v_normal3f)
+#endif
+
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+EAGLER_IN_AUTO(vec2, a_lightmap2f)
+EAGLER_OUT(vec2, v_lightmap2f)
+uniform mat4 u_textureMat4f02;
+#endif
+
+#ifdef _COMPILE_VARYING_POSITION
+uniform mat4 u_modelviewMat4f;
+uniform mat4 u_projectionMat4f;
+#else
+uniform mat4 u_modelviewProjMat4f;
+#ifdef COMPILE_NORMAL_ATTRIB
+uniform mat4 u_modelviewMat4f;
+#endif
+#endif
+
+#define TEX_MAT3(mat4In) mat3(mat4In[0].xyw,mat4In[1].xyw,mat4In[3].xyw)
+
+void main() {
+#ifdef COMPILE_ENABLE_TEX_GEN
+	v_objectPosition3f = a_position3f;
+#endif
+
+#ifdef _COMPILE_VARYING_POSITION
+	v_position4f = u_modelviewMat4f * vec4(a_position3f, 1.0);
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+	vec3 v_textureTmp3f = TEX_MAT3(u_textureMat4f01) * vec3(a_texture2f, 1.0);
+	v_texture2f = v_textureTmp3f.xy / v_textureTmp3f.z;
+#endif
+	
+#ifdef COMPILE_COLOR_ATTRIB
+	v_color4f = a_color4f;
+#endif
+	
+#ifdef COMPILE_NORMAL_ATTRIB
+	v_normal3f = normalize(mat3(u_modelviewMat4f) * a_normal4f.xyz);
+#endif
+	
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+	vec3 v_lightmapTmp3f = TEX_MAT3(u_textureMat4f02) * vec3(a_lightmap2f, 1.0);
+	v_lightmap2f = v_lightmapTmp3f.xy / v_lightmapTmp3f.z;
+#endif
+
+#ifdef _COMPILE_VARYING_POSITION
+	EAGLER_VERT_POSITION = u_projectionMat4f * v_position4f;
+#else
+	EAGLER_VERT_POSITION = u_modelviewProjMat4f * vec4(a_position3f, 1.0);
+#endif
+}

resources/eagler/glsl/gles2_compat.glsl

@@ -0,0 +1,98 @@
+#line 2 6969
+
+/*
+ * Copyright (c) 2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+#ifdef EAGLER_HAS_GLES_300
+
+// For GLES 3.00+ (WebGL 2.0)
+#ifdef EAGLER_IS_VERTEX_SHADER
+
+// Vertex Shaders:
+#define EAGLER_VSH_LAYOUT_BEGIN()
+#define EAGLER_VSH_LAYOUT_END()
+#define EAGLER_IN(_loc, _type, _name) layout(location = _loc) in _type _name;
+#define EAGLER_IN_AUTO(_type, _name) in _type _name;
+#define EAGLER_OUT(_type, _name) out _type _name;
+#define EAGLER_VERT_POSITION gl_Position
+
+#else
+#ifdef EAGLER_IS_FRAGMENT_SHADER
+
+// Fragment Shaders:
+#define EAGLER_IN(_type, _name) in _type _name;
+#define EAGLER_FRAG_COLOR eagler_FragColor
+#define EAGLER_FRAG_DEPTH gl_FragDepth
+
+#define EAGLER_FRAG_OUT() layout(location = 0) out vec4 EAGLER_FRAG_COLOR;
+
+#endif
+#endif
+
+// All Shaders:
+
+#define EAGLER_TEXTURE_2D(tex, coord2f) texture(tex, coord2f)
+#define EAGLER_TEXTURE_2D_LOD(_tex, _coord2f, _lod1f) textureLod(_tex, _coord2f, _lod1f)
+#define EAGLER_HAS_TEXTURE_2D_LOD
+
+
+#else
+#ifdef EAGLER_HAS_GLES_200
+
+// For GLES 2.00 (WebGL 1.0)
+#ifdef EAGLER_IS_VERTEX_SHADER
+
+// Vertex Shaders:
+#define EAGLER_VSH_LAYOUT_BEGIN()
+#define EAGLER_VSH_LAYOUT_END()
+#define EAGLER_IN(_loc, _type, _name) attribute _type _name;
+#define EAGLER_IN_AUTO(_type, _name) attribute _type _name;
+#define EAGLER_OUT(_type, _name) varying _type _name;
+#define EAGLER_VERT_POSITION gl_Position
+
+#else
+#ifdef EAGLER_IS_FRAGMENT_SHADER
+
+// Fragment Shaders:
+#define EAGLER_IN(_type, _name) varying _type _name;
+#define EAGLER_FRAG_COLOR gl_FragColor
+// TODO: Must require EXT_frag_depth to use this on GLES 2.0 (currently not needed)
+#define EAGLER_FRAG_DEPTH gl_FragDepth
+
+#define EAGLER_FRAG_OUT()
+
+#endif
+#endif
+
+// All Shaders:
+
+#define EAGLER_TEXTURE_2D(_tex, _coord2f) texture2D(_tex, _coord2f)
+
+#ifdef EAGLER_HAS_GLES_200_SHADER_TEXTURE_LOD
+#define EAGLER_TEXTURE_2D_LOD(_tex, _coord2f, _lod1f) texture2DLodEXT(_tex, _coord2f, _lod1f)
+#define EAGLER_HAS_TEXTURE_2D_LOD
+#else
+// Beware!
+#define EAGLER_TEXTURE_2D_LOD(_tex, _coord2f, _lod1f) texture2D(_tex, _coord2f)
+#define EAGLER_HAS_TEXTURE_2D_LOD
+#endif
+
+#else
+#error Unable to determine API version! (Missing directive EAGLER_HAS_GLES_200 or 300)
+#endif
+#endif
+
+#line 1 0

resources/eagler/glsl/hw_fingerprint.fsh

@@ -0,0 +1,55 @@
+#line 2
+
+/*
+ * Copyright (c) 2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN(vec2, v_position2f)
+
+EAGLER_FRAG_OUT()
+
+uniform sampler2D u_inputTexture;
+uniform mat4 u_textureMatrix;
+
+vec2 rand(in vec2 co){
+	float f = dot(co, vec2(12.98984576, 78.23378678));
+	return fract(vec2(sin(f + 0.32490982), cos(f - 0.69890)) * 43758.54576873);
+}
+
+void main() {
+	vec4 coords4f = vec4(v_position2f.x * 0.25 - 0.125, v_position2f.y * 0.25 - 0.125, v_position2f.y * 10.0 - 9.0, 1.0);
+	coords4f = u_textureMatrix * coords4f;
+	coords4f.xy /= coords4f.w;
+	EAGLER_FRAG_COLOR = EAGLER_TEXTURE_2D(u_inputTexture, coords4f.xy * 0.5 + 0.5);
+	EAGLER_FRAG_COLOR.rg += rand(v_position2f * 1.2344574345) * 0.05;
+	EAGLER_FRAG_COLOR.ba -= rand(v_position2f * 1.2343525225) * 0.05;
+	EAGLER_FRAG_COLOR.a = fract(sin(dot(coords4f.yz, vec2(12.9898, 78.233))) * 43758.5453);
+	EAGLER_FRAG_COLOR.a += exp(length(rand(coords4f.xw)) * -69.420);
+	EAGLER_FRAG_COLOR = pow(EAGLER_FRAG_COLOR, vec4(1.0 / 2.423952));
+	EAGLER_FRAG_COLOR = pow(EAGLER_FRAG_COLOR, vec4(5.4523856));
+	EAGLER_FRAG_COLOR += 0.00004423 + EAGLER_FRAG_COLOR.a * 0.02;
+	EAGLER_FRAG_COLOR = sqrt(EAGLER_FRAG_COLOR);
+	EAGLER_FRAG_COLOR = pow(EAGLER_FRAG_COLOR, vec4(1.0 / 1.9023576));
+#ifdef EAGLER_HAS_GLES_300
+	EAGLER_FRAG_COLOR.ra += tanh(fract(EAGLER_FRAG_COLOR.a * 32.324834)) * 0.1012426;
+#endif
+	EAGLER_FRAG_COLOR.b *= 0.934924;
+	EAGLER_FRAG_COLOR.b += (1.23213 / inversesqrt(EAGLER_FRAG_COLOR.a)) * 0.156365;
+	EAGLER_FRAG_COLOR.ga += rand(gl_FragCoord.xy) * 0.13423567;
+	EAGLER_FRAG_COLOR.rb += gl_PointCoord * 0.0124264565;
+#ifdef EAGLER_HAS_GLES_300
+	EAGLER_FRAG_COLOR *= 0.95234 + asinh(EAGLER_FRAG_COLOR.g * 5.23423) * 0.0254325;
+#endif
+}

resources/eagler/glsl/local.vsh

@@ -0,0 +1,28 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_VSH_LAYOUT_BEGIN()
+EAGLER_IN(0, vec2, a_position2f)
+EAGLER_VSH_LAYOUT_END()
+
+EAGLER_OUT(vec2, v_position2f)
+
+void main() {
+	v_position2f = a_position2f * 0.5 + 0.5;
+	EAGLER_VERT_POSITION = vec4(a_position2f, 0.0, 1.0);
+}

resources/eagler/glsl/post_fxaa.fsh

@@ -0,0 +1,369 @@
+#line 2
+
+// Remove this line below if you plan to modify this file
+#ifndef EAGLER_IS_GLES_200
+#define USE_OPTIMIZED
+#endif
+
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+
+/*
+ * This file was modified by lax1dude to remove dead code
+ * 
+ * Original: https://gist.github.com/kosua20/0c506b81b3812ac900048059d2383126
+ * 
+ */
+
+
+/*
+ * ============================================================================
+ * 
+ * 
+ *                     NVIDIA FXAA 3.11 by TIMOTHY LOTTES
+ * 
+ * 
+ * ------------------------------------------------------------------------------
+ * COPYRIGHT (C) 2010, 2011 NVIDIA CORPORATION. ALL RIGHTS RESERVED.
+ * ------------------------------------------------------------------------------
+ * TO THE MAXIMUM EXTENT PERMITTED BY APPLICABLE LAW, THIS SOFTWARE IS PROVIDED
+ * *AS IS* AND NVIDIA AND ITS SUPPLIERS DISCLAIM ALL WARRANTIES, EITHER EXPRESS
+ * OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, IMPLIED WARRANTIES OF
+ * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. IN NO EVENT SHALL NVIDIA
+ * OR ITS SUPPLIERS BE LIABLE FOR ANY SPECIAL, INCIDENTAL, INDIRECT, OR
+ * CONSEQUENTIAL DAMAGES WHATSOEVER (INCLUDING, WITHOUT LIMITATION, DAMAGES FOR
+ * LOSS OF BUSINESS PROFITS, BUSINESS INTERRUPTION, LOSS OF BUSINESS INFORMATION,
+ * OR ANY OTHER PECUNIARY LOSS) ARISING OUT OF THE USE OF OR INABILITY TO USE
+ * THIS SOFTWARE, EVEN IF NVIDIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH
+ * DAMAGES.
+ * 
+ */
+
+EAGLER_IN(vec2, v_position2f)
+
+EAGLER_FRAG_OUT()
+
+uniform sampler2D u_screenTexture;
+uniform vec2 u_screenSize2f;
+
+#ifndef USE_OPTIMIZED
+#ifndef FXAA_GREEN_AS_LUMA
+    // For those using non-linear color,
+    // and either not able to get luma in alpha, or not wanting to,
+    // this enables FXAA to run using green as a proxy for luma.
+    // So with this enabled, no need to pack luma in alpha.
+    //
+    // This will turn off AA on anything which lacks some amount of green.
+    // Pure red and blue or combination of only R and B, will get no AA.
+    //
+    // Might want to lower the settings for both,
+    //    fxaaConsoleEdgeThresholdMin
+    //    fxaaQualityEdgeThresholdMin
+    // In order to insure AA does not get turned off on colors 
+    // which contain a minor amount of green.
+    //
+    // 1 = On.
+    // 0 = Off.
+    //
+    #define FXAA_GREEN_AS_LUMA 0
+#endif
+
+#ifndef FXAA_DISCARD
+    // 1 = Use discard on pixels which don't need AA.
+    // 0 = Return unchanged color on pixels which don't need AA.
+    #define FXAA_DISCARD 0
+#endif
+
+/*============================================================================
+                                API PORTING
+============================================================================*/
+    #define FxaaBool bool
+    #define FxaaDiscard discard
+    #define FxaaFloat float
+    #define FxaaFloat2 vec2
+    #define FxaaFloat3 vec3
+    #define FxaaFloat4 vec4
+    #define FxaaHalf float
+    #define FxaaHalf2 vec2
+    #define FxaaHalf3 vec3
+    #define FxaaHalf4 vec4
+    #define FxaaInt2 ivec2
+    #define FxaaSat(x) clamp(x, 0.0, 1.0)
+    #define FxaaTex sampler2D
+/*--------------------------------------------------------------------------*/
+
+    #define FxaaTexTop(t, p) EAGLER_TEXTURE_2D_LOD(t, p, 0.0)
+
+/*============================================================================
+                   GREEN AS LUMA OPTION SUPPORT FUNCTION
+============================================================================*/
+#if (FXAA_GREEN_AS_LUMA == 0)
+    FxaaFloat FxaaLuma(FxaaFloat4 rgba) { return dot(rgba.xyz * rgba.xyz, vec3(0.299, 0.587, 0.114)); }
+#else
+    FxaaFloat FxaaLuma(FxaaFloat4 rgba) { return rgba.y; }
+#endif    
+
+/*============================================================================
+                         FXAA3 CONSOLE - PC VERSION
+============================================================================*/
+/*--------------------------------------------------------------------------*/
+FxaaFloat4 FxaaPixelShader(
+    // See FXAA Quality FxaaPixelShader() source for docs on Inputs!
+    //
+    // Use noperspective interpolation here (turn off perspective interpolation).
+    // {xy} = center of pixel
+    FxaaFloat2 pos,
+    //
+    // Used only for FXAA Console, and not used on the 360 version.
+    // Use noperspective interpolation here (turn off perspective interpolation).
+    // {xy__} = upper left of pixel
+    // {__zw} = lower right of pixel
+    FxaaFloat4 fxaaConsolePosPos,
+    //
+    // Input color texture.
+    // {rgb_} = color in linear or perceptual color space
+    // if (FXAA_GREEN_AS_LUMA == 0)
+    //     {___a} = luma in perceptual color space (not linear)
+    FxaaTex tex,
+    //
+    // Only used on FXAA Console.
+    // This must be from a constant/uniform.
+    // This effects sub-pixel AA quality and inversely sharpness.
+    //   Where N ranges between,
+    //     N = 0.50 (default)
+    //     N = 0.33 (sharper)
+    // {x___} = -N/screenWidthInPixels  
+    // {_y__} = -N/screenHeightInPixels
+    // {__z_} =  N/screenWidthInPixels  
+    // {___w} =  N/screenHeightInPixels 
+    FxaaFloat4 fxaaConsoleRcpFrameOpt,
+    //
+    // Only used on FXAA Console.
+    // Not used on 360, but used on PS3 and PC.
+    // This must be from a constant/uniform.
+    // {x___} = -2.0/screenWidthInPixels  
+    // {_y__} = -2.0/screenHeightInPixels
+    // {__z_} =  2.0/screenWidthInPixels  
+    // {___w} =  2.0/screenHeightInPixels 
+    FxaaFloat4 fxaaConsoleRcpFrameOpt2,
+    // 
+    // Only used on FXAA Console.
+    // This used to be the FXAA_CONSOLE__EDGE_SHARPNESS define.
+    // It is here now to allow easier tuning.
+    // This does not effect PS3, as this needs to be compiled in.
+    //   Use FXAA_CONSOLE__PS3_EDGE_SHARPNESS for PS3.
+    //   Due to the PS3 being ALU bound,
+    //   there are only three safe values here: 2 and 4 and 8.
+    //   These options use the shaders ability to a free *|/ by 2|4|8.
+    // For all other platforms can be a non-power of two.
+    //   8.0 is sharper (default!!!)
+    //   4.0 is softer
+    //   2.0 is really soft (good only for vector graphics inputs)
+    FxaaFloat fxaaConsoleEdgeSharpness,
+    //
+    // Only used on FXAA Console.
+    // This used to be the FXAA_CONSOLE__EDGE_THRESHOLD define.
+    // It is here now to allow easier tuning.
+    // This does not effect PS3, as this needs to be compiled in.
+    //   Use FXAA_CONSOLE__PS3_EDGE_THRESHOLD for PS3.
+    //   Due to the PS3 being ALU bound,
+    //   there are only two safe values here: 1/4 and 1/8.
+    //   These options use the shaders ability to a free *|/ by 2|4|8.
+    // The console setting has a different mapping than the quality setting.
+    // Other platforms can use other values.
+    //   0.125 leaves less aliasing, but is softer (default!!!)
+    //   0.25 leaves more aliasing, and is sharper
+    FxaaFloat fxaaConsoleEdgeThreshold,
+    //
+    // Only used on FXAA Console.
+    // This used to be the FXAA_CONSOLE__EDGE_THRESHOLD_MIN define.
+    // It is here now to allow easier tuning.
+    // Trims the algorithm from processing darks.
+    // The console setting has a different mapping than the quality setting.
+    // This does not apply to PS3, 
+    // PS3 was simplified to avoid more shader instructions.
+    //   0.06 - faster but more aliasing in darks
+    //   0.05 - default
+    //   0.04 - slower and less aliasing in darks
+    // Special notes when using FXAA_GREEN_AS_LUMA,
+    //   Likely want to set this to zero.
+    //   As colors that are mostly not-green
+    //   will appear very dark in the green channel!
+    //   Tune by looking at mostly non-green content,
+    //   then start at zero and increase until aliasing is a problem.
+    FxaaFloat fxaaConsoleEdgeThresholdMin
+) {
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaNw = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.xy));
+    FxaaFloat lumaSw = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.xw));
+    FxaaFloat lumaNe = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.zy));
+    FxaaFloat lumaSe = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.zw));
+/*--------------------------------------------------------------------------*/
+    FxaaFloat4 rgbyM = FxaaTexTop(tex, pos.xy);
+    #if (FXAA_GREEN_AS_LUMA == 0)
+	    // TODO Luma
+        FxaaFloat lumaM = FxaaLuma(rgbyM);
+    #else
+        FxaaFloat lumaM = rgbyM.y;
+    #endif
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaMaxNwSw = max(lumaNw, lumaSw);
+    lumaNe += 1.0/384.0;
+    FxaaFloat lumaMinNwSw = min(lumaNw, lumaSw);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaMaxNeSe = max(lumaNe, lumaSe);
+    FxaaFloat lumaMinNeSe = min(lumaNe, lumaSe);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaMax = max(lumaMaxNeSe, lumaMaxNwSw);
+    FxaaFloat lumaMin = min(lumaMinNeSe, lumaMinNwSw);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaMaxScaled = lumaMax * fxaaConsoleEdgeThreshold;
+/*--------------------------------------------------------------------------*/
+    FxaaFloat lumaMinM = min(lumaMin, lumaM);
+    FxaaFloat lumaMaxScaledClamped = max(fxaaConsoleEdgeThresholdMin, lumaMaxScaled);
+    FxaaFloat lumaMaxM = max(lumaMax, lumaM);
+    FxaaFloat dirSwMinusNe = lumaSw - lumaNe;
+    FxaaFloat lumaMaxSubMinM = lumaMaxM - lumaMinM;
+    FxaaFloat dirSeMinusNw = lumaSe - lumaNw;
+    if(lumaMaxSubMinM < lumaMaxScaledClamped) 
+    {
+      #if (FXAA_DISCARD == 1)
+        FxaaDiscard;
+      #else
+        return rgbyM;
+      #endif
+    }
+/*--------------------------------------------------------------------------*/
+    FxaaFloat2 dir;
+    dir.x = dirSwMinusNe + dirSeMinusNw;
+    dir.y = dirSwMinusNe - dirSeMinusNw;
+/*--------------------------------------------------------------------------*/
+    FxaaFloat2 dir1 = normalize(dir.xy);
+    FxaaFloat4 rgbyN1 = FxaaTexTop(tex, pos.xy - dir1 * fxaaConsoleRcpFrameOpt.zw);
+    FxaaFloat4 rgbyP1 = FxaaTexTop(tex, pos.xy + dir1 * fxaaConsoleRcpFrameOpt.zw);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat dirAbsMinTimesC = min(abs(dir1.x), abs(dir1.y)) * fxaaConsoleEdgeSharpness;
+    FxaaFloat2 dir2 = clamp(dir1.xy / dirAbsMinTimesC, -2.0, 2.0);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat2 dir2x = dir2 * fxaaConsoleRcpFrameOpt2.zw;
+    FxaaFloat4 rgbyN2 = FxaaTexTop(tex, pos.xy - dir2x);
+    FxaaFloat4 rgbyP2 = FxaaTexTop(tex, pos.xy + dir2x);
+/*--------------------------------------------------------------------------*/
+    FxaaFloat4 rgbyA = rgbyN1 + rgbyP1;
+    FxaaFloat4 rgbyB = ((rgbyN2 + rgbyP2) * 0.25) + (rgbyA * 0.25);
+/*--------------------------------------------------------------------------*/
+    #if (FXAA_GREEN_AS_LUMA == 0)
+      // TODO Luma
+      float lumaB = FxaaLuma(rgbyB);
+    #else
+      float lumaB = rgbyB.y;
+    #endif
+    if((lumaB < lumaMin) || (lumaB > lumaMax)) 
+      rgbyB.xyz = rgbyA.xyz * 0.5;
+    //
+    return rgbyB; 
+}
+/*==========================================================================*/
+
+#define edgeSharpness 3.0
+#define edgeThreshold 0.15
+#define edgeThresholdMin 0.05
+
+void main(){
+	vec2 screenSize05 = 0.5 * u_screenSize2f;
+
+	vec4 posPos;
+	posPos.xy = v_position2f;
+	posPos.zw = v_position2f + u_screenSize2f;
+
+	vec4 rcpFrameOpt;
+	rcpFrameOpt.xy = -screenSize05;
+	rcpFrameOpt.zw = screenSize05;
+
+	EAGLER_FRAG_COLOR = vec4(FxaaPixelShader(v_position2f + screenSize05, posPos, u_screenTexture, rcpFrameOpt, rcpFrameOpt * 4.0, edgeSharpness, edgeThreshold, edgeThresholdMin).rgb, 1.0);
+}
+#else
+
+// This 'optimized' code was generated using glslangValidator + spirv-cross + spirv-opt on the source code above
+// Is it faster? Idfk, probably compiles faster at least, what matters it I tried
+
+float _616;
+
+void main()
+{
+    mediump vec2 _257 = u_screenSize2f * 0.5;
+    mediump vec4 _611 = vec4(v_position2f, v_position2f + u_screenSize2f);
+    mediump vec4 _612 = vec4(_616, _616, _257);
+    mediump vec2 _290 = v_position2f + _257;
+    mediump vec4 _608;
+    for(;;)
+    {
+        mediump vec3 _532 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, _611.xy, 0.0).xyz;
+        mediump float _536 = dot(_532 * _532, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625));
+        mediump vec3 _540 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, _611.xw, 0.0).xyz;
+        mediump float _544 = dot(_540 * _540, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625));
+        mediump vec3 _548 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, _611.zy, 0.0).xyz;
+        mediump vec3 _556 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, _611.zw, 0.0).xyz;
+        mediump float _560 = dot(_556 * _556, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625));
+        mediump vec4 _390 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, _290, 0.0);
+        mediump vec3 _564 = _390.xyz;
+        mediump float _568 = dot(_564 * _564, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625));
+        mediump float _397 = dot(_548 * _548, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625)) + 0.00260416674427688121795654296875;
+        mediump float _409 = max(max(_397, _560), max(_536, _544));
+        mediump float _412 = min(min(_397, _560), min(_536, _544));
+        mediump float _427 = _544 - _397;
+        mediump float _433 = _560 - _536;
+        if ((max(_409, _568) - min(_412, _568)) < max(0.0500000007450580596923828125, _409 * 0.1500000059604644775390625))
+        {
+            _608 = _390;
+            break;
+        }
+        mediump vec2 _449 = normalize(vec2(_427 + _433, _427 - _433));
+        vec2 hp_copy_449 = _449;
+        mediump vec2 _454 = _612.zw;
+        vec2 _614 = -hp_copy_449;
+        mediump vec2 mp_copy_614 = _614;
+        mediump vec2 _481 = clamp(_449 / vec2(min(abs(_449.x), abs(_449.y)) * 3.0), vec2(-2.0), vec2(2.0));
+        vec2 hp_copy_481 = _481;
+        mediump vec2 _484 = (_612 * 4.0).zw;
+        vec2 _615 = -hp_copy_481;
+        mediump vec2 mp_copy_615 = _615;
+        mediump vec4 _498 = EAGLER_TEXTURE_2D_LOD(u_screenTexture, mp_copy_614 * _454 + _290, 0.0) + EAGLER_TEXTURE_2D_LOD(u_screenTexture, _449 * _454 + _290, 0.0);
+        mediump vec4 _505 = ((EAGLER_TEXTURE_2D_LOD(u_screenTexture, mp_copy_615 * _484 + _290, 0.0) + EAGLER_TEXTURE_2D_LOD(u_screenTexture, _481 * _484 + _290, 0.0)) * 0.25) + (_498 * 0.25);
+        mediump float _576 = dot(_505.xyz * _505.xyz, vec3(0.2989999949932098388671875, 0.58700001239776611328125, 0.114000000059604644775390625));
+        mediump vec4 _607;
+        if ((_576 < _412) || (_576 > _409))
+        {
+            mediump vec3 _518 = _498.xyz * 0.5;
+            mediump vec4 _600;
+            _600.x = _518.x;
+            _600.y = _518.y;
+            _600.z = _518.z;
+            _607 = _600;
+        }
+        else
+        {
+            _607 = _505;
+        }
+        _608 = _607;
+        break;
+    }
+    EAGLER_FRAG_COLOR = vec4(_608.xyz, 1.0);
+}
+
+#endif

resources/eagler/glsl/texture_blit.fsh

@@ -0,0 +1,43 @@
+#line 2
+
+/*
+ * Copyright (c) 2023-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN(vec2, v_texCoords2f)
+
+#ifndef COMPILE_BLIT_DEPTH
+EAGLER_FRAG_OUT()
+#endif
+
+uniform sampler2D u_inputTexture;
+uniform float u_textureLod1f;
+
+#ifdef COMPILE_PIXEL_ALIGNMENT
+uniform vec4 u_pixelAlignmentSizes4f;
+uniform vec2 u_pixelAlignmentOffset2f;
+#endif
+
+void main() {
+	vec2 uv2f = v_texCoords2f;
+#ifdef COMPILE_PIXEL_ALIGNMENT
+	uv2f = (floor(uv2f * u_pixelAlignmentSizes4f.xy) + u_pixelAlignmentOffset2f) * u_pixelAlignmentSizes4f.zw;
+#endif
+#ifndef COMPILE_BLIT_DEPTH
+	EAGLER_FRAG_COLOR = EAGLER_TEXTURE_2D_LOD(u_inputTexture, uv2f, u_textureLod1f);
+#else
+	EAGLER_FRAG_DEPTH = EAGLER_TEXTURE_2D_LOD(u_inputTexture, uv2f, u_textureLod1f).r;
+#endif
+}

resources/eagler/glsl/texture_blit.vsh

@@ -0,0 +1,32 @@
+#line 2
+
+/*
+ * Copyright (c) 2023-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_VSH_LAYOUT_BEGIN()
+EAGLER_IN(0, vec2, a_position2f)
+EAGLER_VSH_LAYOUT_END()
+
+EAGLER_OUT(vec2, v_texCoords2f)
+
+uniform vec4 u_srcCoords4f;
+uniform vec4 u_dstCoords4f;
+
+void main() {
+	vec2 uv = a_position2f * 0.5 + 0.5;
+	v_texCoords2f = u_srcCoords4f.xy + u_srcCoords4f.zw * uv;
+	EAGLER_VERT_POSITION = vec4(u_dstCoords4f.xy + u_dstCoords4f.zw * uv, 0.0, 1.0);
+}

resources/eagler/glsl/texture_mix.fsh

@@ -0,0 +1,33 @@
+#line 2
+
+/*
+ * Copyright (c) 2022-2024 lax1dude. All Rights Reserved.
+ * 
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+ * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ * 
+ */
+
+EAGLER_IN(vec2, v_position2f)
+
+EAGLER_FRAG_OUT()
+
+uniform sampler2D u_inputTexture;
+uniform float u_textureLod1f;
+uniform vec4 u_blendFactor4f;
+uniform vec4 u_blendBias4f;
+uniform mat3 u_matrixTransform;
+
+void main() {
+	vec3 coords = u_matrixTransform * vec3(v_position2f, 1.0);
+	vec4 color4f = EAGLER_TEXTURE_2D_LOD(u_inputTexture, coords.xy, u_textureLod1f);
+	EAGLER_FRAG_COLOR = color4f * u_blendFactor4f + u_blendBias4f;
+}